*** EXAMPLE TO CREATE A DATA SET "HTWT" AND TO COMPUTE DESCRIPTIVE STATISTICS;
DATA HTWT;
	INPUT 	SUBJ
			GENDER $
			HEIGHT
			WEIGHT
			COLLEGE $;
DATALINES;
1 M 68.5 155 SCI
2 F 61.2 99 BSNS
3 F 63.0 115 BSNS
4 M 70.0 205 SCI
5 M 68.6 170 ENG
6 F 65.1 125 BSNS
7 M 72.4 220 ENG
8 M . 188 SCI
;
** NUMERICAL SUMMARIES FOR QUANTITATIVE VAR'S;
PROC MEANS DATA=HTWT;
	TITLE "SIMPLE DESCRIPTIVE STATISTICS 1";
RUN;
PROC MEANS DATA=HTWT N MEAN STD STDERR CLM;
	TITLE "SIMPLE DESCRIPTIVE STATISTICS 2";
RUN;
PROC UNIVARIATE DATA=HTWT NORMAL PLOT;
	TITLE "MORE DESCRIPTIVE STATISTICS";
	VAR HEIGHT;
RUN;
** STATISITCS BY GROUPS;
PROC SORT DATA=HTWT;
	BY GENDER;
RUN;

PROC MEANS DATA=HTWT;
	TITLE "SIMPLE DESCRIPTIVE STATISTICS BY GENDER";
	BY GENDER; ** BY GIVES THE BREAKDOWN;
	VAR HEIGHT;
RUN;
** NUMERICAL AND VISUAL SUMMARIES FOR QUANTITATIVE VAR'S;
PROC UNIVARIATE DATA=HTWT;
	TITLE "MORE DESCRIPTIVE STATISTICS + HISTOGRAMS";
	BY GENDER;
	VAR HEIGHT;
	HISTOGRAM HEIGHT / MIDPOINTS=60 TO 75 BY 5 NORMAL;
	INSET 	MEAN='MEAN' (5.2)
			STD='STANDARD DEVIATION' (5.2); 
	* PLEASE SEE MANU FOR FANCY ARRANGMENT SUCH AS FONT, POSITION, AND SO ON;
	QQPLOT HEIGHT;
	PROBPLOT HEIGHT;
RUN;
** VISUAL SUMMARY FOR TWO QUANTITATIVE VAR'S;
PROC GPLOT DATA=HTWT;
	TITLE "SCATTERPLOT FOR WEIGHT BY HEIGHT";
	PLOT WEIGHT*HEIGHT;
RUN;
PROC GPLOT DATA=HTWT;
	TITLE "SCATTERPLOT FOR WEIGHT BY HEIGHT WITH GENDER GROUP";
	PLOT WEIGHT*HEIGHT=GENDER;
RUN;
** VISUAL SUMMARY FOR CATEGORICAL VAR'S;
PROC GCHART DATA=HTWT;
	TITLE "BAR CHART";
	VBAR COLLEGE;
RUN;
PROC GCHART DATA=HTWT;
	TITLE "BAR CHART BY GENDER";
	BY GENDER;
	VBAR COLLEGE;
RUN;